This following sample request identifies addresses for faculty paid by your campus in the prior business month. A match is needed between the Payment History (PH) - prior business month file which contains the targeted employees, and the Active Current Status (AC) file which has address information for active employees. To identify the address for employees who have separated since the payment was issued, an additional match is needed with the Separated Positions (SP) file. Refer to the notes in the report request below for additional information. The request is in the CIRS common library as FOC5002.
Sample Output (comma delimited file):
"222-22-2222","MONKEY, MM ","400 40TH AVE ","SACRAMENTO, CA ","99999"
"888-88-8888","BEAR, JR ","123 MAIN ST ","SAN FRANCSICO, CA","99999"
Report Request:
-****************************************************************
-* ALL REQUIRED DEFINES MUST BE EXECUTED BEFORE THE MATCH COMMAND.
-*****************************************************************
EX PH
EX AC
EX SP
-*****************************************************************
-* THE LINES BELOW IDENTIFY R03 EE'S PAID IN THE PRIOR PAY PERIOD.
-* EMPLOYEE NAME IS SUMMED SO ONLY ONE RECORD IS SELECTED.
-******************************************************************
MATCH FILE PH
SUM PH:WNAME
BY PH:SSA AS 'SSA'
IF PH:CBID EQ R03
IF PH:CAMPX EQ _
IF PH:PAYPERIOD EQ 2005/01
RUN
-***********************************************************
-* THE LINES BELOW GATHER ADDRESS FOR ACTIVE POSITIONS
-* AND MATCHES THE DATA TO THE SSN'S SELECTED FROM PH FILE.
-* THE MATCH OPTION 'OLD' IS USED TO KEEP ALL THE RECORDS FROM
_* THE PH FILE AND ONLY BRING IN MATCHING AC RECORDS.
-* THE RESULTING MATCHED DATA IS HELD TO PERMSML.
-***********************************************************
FILE AC
PRINT AC:STREET AC:CTYST AC:ZIP
BY AC:SSA AS 'SSA'
AFTER MATCH HOLD AS PERMSML OLD
END
-***********************************************************
-* THE LINE BELOW GATHERS ADDRESS FOR SEPARATED POSITIONS
-* AND MATCHES IT TO THE DATA HELD IN PERMSML.
-* THE RESULTING MATCHED DATA IS HELD TO PERMLRG
-***********************************************************
MATCH FILE PERMSML
PRINT PH:WNAME AC:STREET AC:CTYST AC:ZIP
BY SSA
RUN
-*
FILE SP
PRINT SP:STREET SP:CTYST SP:ZIP
BY SP:SSA AS 'SSA'
AFTER MATCH HOLD AS PERMLRG OLD
END
-***********************************************************
-*THE DEFINES BELOW MERGE THE ADDRESS FIELDS FROM AC AND SP.
-************************************************************
DEFINE FILE PERMRLG
STREET/A28 = IF AC:STREET EQ ' ' THEN SP:STREET ELSE AC:STREET;
CTYST/A25 = IF AC:CTYST EQ ' ' THEN SP:CTYST ELSE AC:CTYST;
ZIP/A5 = IF AC:ZIP EQ ' ' THEN SP:ZIP ELSE AC:ZIP;
END
-**********************************************************
-* THE LINES BELOW GENERATE THE FINAL FILE FOR DOWNLOADING.
-**********************************************************
TABLE FILE PERMLRG
PRINT SSA PH:WNAME STREET CTYST ZIP
ON TABLE HOLD AS PERMRPT FORMAT LOTUS
END
Last Updated: March 1, 2024