Below are several sample FOCUS reports that use the PH file.
|
FOC1060
|
Total Gross Pay and Deduction Amounts By Pay Period
|
|
FOC1090
|
CSUEU Dental Plan Enrollments
|
Report Request: FOC1060
The following sample program sums gross pay and deduction amounts by pay period and fiscal year. Since FOCUS will not include gross pay when referencing fields in deduction segments, if there are no deductions for that payment, a match is needed between the payment and deduction segments. The match option OLD is used to ensure all occurrences of payment data is retained while incorporating deduction data.
EX PH
MATCH FILE PH
SUM PH:GROSSPAY
BY PH:PAYPERIOD
WHERE PH:PAYPERIOD FROM 200307 TO 200406
RUN
-*
FILE PH
SUM PH:DEDAMT
BY PH:PAYPERIOD AS 'PAY,PERIOD'
IF PH:PAYPERIOD FROM 200307 TO 200406
AFTER MATCH HOLD AS PERMLRG OLD
END
-*
TABLE FILE PERMLRG
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"TOTAL GROSS AND DEDUCTIONS BY PAY PERIOD"
"COMMON(FOC1060)"
" "
PRINT ph:grosspay as 'total,gross amt'
ph:dedamt as 'total,ded amt'
by ph:payperiod as 'pay,period'
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
TOTAL GROSS AND DEDUCTIONS BY PAY PERIOD
COMMON (FOC1060)
PAY total total
PERIOD GROSS AMT DED AMT
------ --------- ------
200307 $ 9,097.41 $ .00
200308 $ 7,794,391.59 $ 932,192.44
200309 $ 1,424.50 $ .00
200310 $ 8,167,089.08 $ 920,328.39
200311 $ 8.09 $ .00
200312 $ 7,589,874.31 $ 901,003.39
200401 $ 7,642,529.62 $ 901,500.46
200402 $ 7,619,442.98 $ 888,250.34
200403 $ 7,566,248.78 $ 894,036.62
200404 $ 7,919,595.65 $ 905,016.93
200405 $ 7,538,306.05 $ 899,791.63
200406 $ 7,634,994.65 $ 908,433.55
Report Request: FOC1090
The following sample program counts CSUEU dental plan enrollments. The join JPHAG is used to get data from Fund Name from the Agency/Campus/Fund (AG) file. A hold file is used in combination with a define to count SSN's only once.
EX JPHAG
TABLE FILE PH
PRINT PH:SSA PH:HBPRTCD FUND
WHERE PH:PAYPERIOD EQ 200302
WHERE PH:CBID EQ 'R02' OR 'R05' OR 'R07' OR 'R09'
WHERE PH:DEDTYPE EQ 'HD'
WHERE PH:HBSTATE GT 0
WHERE RECORDLIMIT EQ 100
-*** REMOVE RECORDLIMIT AFTER TESTING ***
ON TABLE HOLD AS PERMSML
END
DEFINE FILE PERMSML
CATEGORY/A6 = IF PH:HBPRTCD EQ '1' THEN ' EE' ELSE
IF PH:HBPRTCD EQ '2' THEN 'EE + 1' ELSE 'EE + 2';
COUNT/I7C = IF PH:SSA EQ LAST PH:SSA THEN 0 ELSE 1;
END
-*
TABLE FILE PERMSML
HEADING CENTER
"THE CALIFORNIA STATE UNIVERSITY"
"CSUEU DENTAL PLAN ENROLLMENTS"
"BY FUND AND DEPENDENT CATEGORY"
"COMMON FOCEXEC: FOC1090 </1"
SUM COUNT
BY FUND
ACROSS CATEGORY AS ''
ON TABLE COLUMN-TOTAL ROW-TOTAL/R
END
The following is only an excerpt from the actual report.
THE CALIFORNIA STATE UNIVERSITY
CSUEU DENTAL PLAN ENROLLMENTS
BY FUND AND DEPENDENT CATEGORY
COMMON FOCEXEC: FOC1090
EE EE + 1 EE + 2 TOTAL
FUND
---------------------------------------------------------
CONTINUING EDUCATI 1 . . 1
GENERAL FUND 33 31 26 90
HOUSING . . 1 1
REIMBURSED ACTIVIT 3 1 . 4
SPECIAL PROJECTS 3 1 . 4
TOTAL 40 33 27 100